VB.NET XmlSchemaFractionDigitsFacet类代码示例

OGeek|极客世界-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Xml.Schema.XmlSchemaFractionDigitsFacet类的典型用法代码示例。如果您正苦于以下问题：VB.NET XmlSchemaFractionDigitsFacet类的具体用法？VB.NET XmlSchemaFractionDigitsFacet怎么用？VB.NET XmlSchemaFractionDigitsFacet使用的例子？那么恭喜您, 这里精选的类代码示例或许可以为您提供帮助。

在下文中一共展示了XmlSchemaFractionDigitsFacet类的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: XMLSchemaExamples

' 导入命名空间
Imports System.Xml
Imports System.Xml.Schema

Class XMLSchemaExamples
    Public Shared Sub Main()

        Dim schema As New XmlSchema()

        '<xs:simpleType name="RatingType">
        Dim RatingType As New XmlSchemaSimpleType()
        RatingType.Name = "RatingType"

        '<xs:restriction base="xs:number">
        Dim restriction As New XmlSchemaSimpleTypeRestriction()
        restriction.BaseTypeName = New XmlQualifiedName("decimal", "http://www.w3.org/2001/XMLSchema")

        '<xs:totalDigits value="2"/>
        Dim totalDigits As New XmlSchemaTotalDigitsFacet()
        totalDigits.Value = "2"
        restriction.Facets.Add(totalDigits)

        '<xs:fractionDigits value="1"/>
        Dim fractionDigits As New XmlSchemaFractionDigitsFacet()
        fractionDigits.Value = "1"
        restriction.Facets.Add(fractionDigits)

        RatingType.Content = restriction
        schema.Items.Add(RatingType)

        '<xs:element name="movie">
        Dim element As New XmlSchemaElement()
        element.Name = "movie"

        '<xs:complexType>
        Dim complexType As New XmlSchemaComplexType()

        '<xs:attribute name="rating" type="RatingType"/>
        Dim ratingAttribute As New XmlSchemaAttribute()
        ratingAttribute.Name = "rating"
        ratingAttribute.SchemaTypeName = New XmlQualifiedName("RatingType", "")
        complexType.Attributes.Add(ratingAttribute)

        element.SchemaType = complexType

        schema.Items.Add(element)

        Dim schemaSet As New XmlSchemaSet()
        AddHandler schemaSet.ValidationEventHandler, AddressOf ValidationCallbackOne

        schemaSet.Add(schema)
        schemaSet.Compile()

        Dim compiledSchema As XmlSchema = Nothing

        For Each schema1 As XmlSchema In schemaSet.Schemas()
            compiledSchema = schema1
        Next

        Dim nsmgr As New XmlNamespaceManager(New NameTable())
        nsmgr.AddNamespace("xs", "http://www.w3.org/2001/XMLSchema")
        compiledSchema.Write(Console.Out, nsmgr)

    End Sub

    Public Shared Sub ValidationCallbackOne(ByVal sender As Object, ByVal args As ValidationEventArgs)
        Console.WriteLine(args.Message)
    End Sub
End Class

开发者ID:VB.NET开发者，项目名称:System.Xml.Schema，代码行数:69，代码来源:XmlSchemaFractionDigitsFacet

注：本文中的System.Xml.Schema.XmlSchemaFractionDigitsFacet类示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。