本文整理汇总了VB.NET中System.Web.UI.Design.WebControls.LoginViewDesigner类的典型用法代码示例。如果您正苦于以下问题:VB.NET LoginViewDesigner类的具体用法?VB.NET LoginViewDesigner怎么用?VB.NET LoginViewDesigner使用的例子?那么恭喜您, 这里精选的类代码示例或许可以为您提供帮助。
在下文中一共展示了LoginViewDesigner类的1个代码示例,这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞,您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。
示例1: PreFilterProperties
' 导入命名空间
Imports System.Web
Imports System.Web.UI.WebControls
Imports System.Web.UI.Design
Imports System.Web.UI.Design.WebControls
Imports System.Collections
Imports System.ComponentModel
Imports System.Security.Permissions
Imports System.IO
Namespace Examples.VB.WebControls.Design
' The MyLoginView is a copy of the LoginView.
<AspNetHostingPermission(SecurityAction.Demand, _
Level:=AspNetHostingPermissionLevel.Minimal)> _
<AspNetHostingPermission(SecurityAction.InheritanceDemand, _
Level:=AspNetHostingPermissionLevel.Minimal)> _
<Designer(GetType(Examples.VB.WebControls.Design.MyLoginViewDesigner))> _
Public Class MyLoginView
Inherits LoginView
End Class
' Override members of the LoginViewDesigner.
<ReflectionPermission(SecurityAction.Demand, Flags:=ReflectionPermissionFlag.MemberAccess)> _
Public Class MyLoginViewDesigner
Inherits LoginViewDesigner
' Generate the design-time markup for the control when an error occurs.
Protected Overrides Function GetErrorDesignTimeHtml( _
ByVal ex As Exception) As String
' Write the error message text in red, bold.
Dim errorRendering As String = _
"<span style=""font-weight:bold; color:Red; "">" & _
ex.Message & "</span>"
Return CreatePlaceHolderDesignTimeHtml(errorRendering)
End Function ' GetErrorDesignTimeHtml
' Generate the design-time markup for the control
' when the template is empty.
Protected Overrides Function GetEmptyDesignTimeHtml() As String
' Generate a design-time placeholder containing the names of all
' the role groups.
Dim myLoginViewCtl As MyLoginView = CType(ViewControl, MyLoginView)
Dim roleGroups As RoleGroupCollection = myLoginViewCtl.RoleGroups
Dim RoleNames As String = Nothing
Dim rgX As Integer
' If there are any role groups, form a string of their names.
If roleGroups.Count > 0 Then
roleNames = "Role Groups: <br /> " & _
roleGroups(0).ToString()
For rgX = 1 To roleGroups.Count - 1
roleNames &= "<br /> " & _
roleGroups(rgX).ToString()
Next rgX
End If
Return CreatePlaceHolderDesignTimeHtml(roleNames)
End Function ' GetEmptyDesignTimeHtml
' Shadow control properties with design-time properties.
Protected Overrides Sub PreFilterProperties( _
ByVal properties As IDictionary)
' Call the base method first.
MyBase.PreFilterProperties(properties)
' Make the NamingContainer visible in the Properties grid.
Dim selectProp As PropertyDescriptor = _
CType(properties("NamingContainer"), PropertyDescriptor)
properties("NamingContainer") = _
TypeDescriptor.CreateProperty(selectProp.ComponentType, _
selectProp, BrowsableAttribute.Yes)
End Sub
' Generate the design-time markup.
Public Overrides Function GetDesignTimeHtml( _
ByVal regions As DesignerRegionCollection) As String
' Make the control more visible in the designer.
' Enclose the markup in a table with an orange border.
Dim openTableMarkup As String = _
"<table><tr><td style=""border:4 solid #FF7F00;"">"
Dim closeTableMarkup As String = "</td></tr></table>"
' Call the base method to generate the markup.
Dim markup As String = MyBase.GetDesignTimeHtml(regions)
Return openTableMarkup & markup & closeTableMarkup
End Function ' GetDesignTimeHtml
' Generate the design time markup.
Public Overrides Sub Initialize(ByVal component As IComponent)
' Ensure that only a MyLoginView can be created in this designer.
If Not TypeOf component Is MyLoginView Then
Throw New ArgumentException()
End If
' Call the base method to generate the markup.
MyBase.Initialize(component)
End Sub
End Class
End Namespace ' Examples.VB.WebControls.Design
开发者ID:VB.NET开发者,项目名称:System.Web.UI.Design.WebControls,代码行数:114,代码来源:LoginViewDesigner
注:本文中的System.Web.UI.Design.WebControls.LoginViewDesigner类示例由纯净天空整理自Github/MSDocs等源码及文档管理平台,相关代码片段筛选自各路编程大神贡献的开源项目,源码版权归原作者所有,传播和使用请参考对应项目的License;未经允许,请勿转载。 |
请发表评论