VB.NET HttpListenerResponse.Cookies属性代码示例

OGeek|极客世界-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Net.HttpListenerResponse.Cookies属性的典型用法代码示例。如果您正苦于以下问题：VB.NET HttpListenerResponse.Cookies属性的具体用法？VB.NET HttpListenerResponse.Cookies怎么用？VB.NET HttpListenerResponse.Cookies使用的例子？那么恭喜您, 这里精选的属性代码示例或许可以为您提供帮助。

在下文中一共展示了HttpListenerResponse.Cookies属性的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: SimpleListenerCookieExample

' This example requires the System and System.Net namespaces.
Public Shared Function NextCustomerID() As String
    ' A real-world application would do something more robust
    ' to ensure uniqueness.
    Return DateTime.Now.ToString()
End Function

Public Shared Sub SimpleListenerCookieExample(ByVal prefixes As String())
    ' Create a listener
    Dim listener As HttpListener = New HttpListener()

    ' Add the prefixes
    For Each s As String In prefixes
        listener.Prefixes.Add(s)
    Next

    listener.IgnoreWriteExceptions = True
    listener.Start()
    Console.WriteLine("Listening...")
    ' Note: The GetContext method blocks while waiting for a request. 
    Dim context As HttpListenerContext = listener.GetContext()
    Dim request As HttpListenerRequest = context.Request
    Dim customerID As String = Nothing

    ' Did the request come with a cookie?
    Dim cookie As Cookie = request.Cookies("ID")

    If cookie IsNot Nothing Then
        customerID = cookie.Value
    End If

    If customerID IsNot Nothing Then
        Console.WriteLine("Found the cookie!")
    End If

    ' Get the response object.
    Dim response As HttpListenerResponse = context.Response
    ' If they didn't provide a cookie containing their ID, give them one.
    If customerID Is Nothing Then
        customerID = NextCustomerID()
        Dim cook As Cookie = New Cookie("ID", customerID)
        response.AppendCookie(cook)
    End If
    ' Construct a response.
    Dim responseString As String = "<HTML><BODY> Hello " & customerID & "!</BODY></HTML>"
    Dim buffer As Byte() = System.Text.Encoding.UTF8.GetBytes(responseString)
    ' Get the response stream and write the response to it.
    response.ContentLength64 = buffer.Length
    Dim output As System.IO.Stream = response.OutputStream
    output.Write(buffer, 0, buffer.Length)
    ' You must close the output stream.
    output.Close()
    response.Close()
    listener.Stop()
End Sub

开发者ID:VB.NET开发者，项目名称:System.Net，代码行数:55，代码来源:HttpListenerResponse.Cookies

注：本文中的System.Net.HttpListenerResponse.Cookies属性示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。