VB.NET XmlSchemaMinExclusiveFacet类代码示例

OGeek|极客世界-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Xml.Schema.XmlSchemaMinExclusiveFacet类的典型用法代码示例。如果您正苦于以下问题：VB.NET XmlSchemaMinExclusiveFacet类的具体用法？VB.NET XmlSchemaMinExclusiveFacet怎么用？VB.NET XmlSchemaMinExclusiveFacet使用的例子？那么恭喜您, 这里精选的类代码示例或许可以为您提供帮助。

在下文中一共展示了XmlSchemaMinExclusiveFacet类的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: XMLSchemaExamples

' 导入命名空间
Imports System.Xml
Imports System.Xml.Schema

Class XMLSchemaExamples
    Public Shared Sub Main()

        Dim schema As New XmlSchema()

        ' <xs:simpleType name="OrderQuantityType">
        Dim OrderQuantityType As New XmlSchemaSimpleType()
        OrderQuantityType.Name = "OrderQuantityType"

        ' <xs:restriction base="xs:int">
        Dim restriction As New XmlSchemaSimpleTypeRestriction()
        restriction.BaseTypeName = New XmlQualifiedName("int", "http://www.w3.org/2001/XMLSchema")

        ' <xs:minExclusive value="5"/>
        Dim MinExclusive As New XmlSchemaMinExclusiveFacet()
        MinExclusive.Value = "5"
        restriction.Facets.Add(MinExclusive)

        OrderQuantityType.Content = restriction

        schema.Items.Add(OrderQuantityType)

        ' <xs:element name="item">
        Dim element As New XmlSchemaElement()
        element.Name = "item"

        ' <xs:complexType>
        Dim complexType As New XmlSchemaComplexType()

        ' <xs:attribute name="OrderQuantity" type="OrderQuantityType"/>
        Dim OrderQuantityAttribute As New XmlSchemaAttribute()
        OrderQuantityAttribute.Name = "OrderQuantity"
        OrderQuantityAttribute.SchemaTypeName = New XmlQualifiedName("OrderQuantityType", "")
        complexType.Attributes.Add(OrderQuantityAttribute)

        element.SchemaType = complexType

        schema.Items.Add(element)

        Dim schemaSet As New XmlSchemaSet()
        AddHandler schemaSet.ValidationEventHandler, AddressOf ValidationCallbackOne

        schemaSet.Add(schema)
        schemaSet.Compile()

        Dim compiledSchema As XmlSchema = Nothing

        For Each schema1 As XmlSchema In schemaSet.Schemas()
            compiledSchema = schema1
        Next

        Dim nsmgr As New XmlNamespaceManager(New NameTable())
        nsmgr.AddNamespace("xs", "http://www.w3.org/2001/XMLSchema")
        compiledSchema.Write(Console.Out, nsmgr)

    End Sub

    Public Shared Sub ValidationCallbackOne(ByVal sender As Object, ByVal args As ValidationEventArgs)
        Console.WriteLine(args.Message)
    End Sub

End Class

开发者ID:VB.NET开发者，项目名称:System.Xml.Schema，代码行数:66，代码来源:XmlSchemaMinExclusiveFacet

注：本文中的System.Xml.Schema.XmlSchemaMinExclusiveFacet类示例整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。