VB.NET SemaphoreSlim类代码示例

OGeek|极客世界-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Threading.SemaphoreSlim类的典型用法代码示例。如果您正苦于以下问题：VB.NET SemaphoreSlim类的具体用法？VB.NET SemaphoreSlim怎么用？VB.NET SemaphoreSlim使用的例子？那么恭喜您, 这里精选的类代码示例或许可以为您提供帮助。

在下文中一共展示了SemaphoreSlim类的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: Example

' 导入命名空间
Imports System.Threading
Imports System.Threading.Tasks

Module Example
   Private semaphore As SemaphoreSlim
    ' A padding interval to make the output more orderly.
    Private padding As Integer

   Public Sub Main()
      ' Create the semaphore.
      semaphore = New SemaphoreSlim(0, 3)
      Console.WriteLine("{0} tasks can enter the semaphore.",
                        semaphore.CurrentCount)
      Dim tasks(4) As Task

      ' Create and start five numbered tasks.
      For i As Integer = 0 To 4
         tasks(i) = Task.Run(
            Sub()
               ' Each task begins by requesting the semaphore.
               Console.WriteLine("Task {0} begins and waits for the semaphore.",
                              Task.CurrentId)
               semaphore.Wait()

               Interlocked.Add(padding, 100)

               Console.WriteLine("Task {0} enters the semaphore.", Task.CurrentId)

               ' The task just sleeps for 1+ seconds.
               Thread.Sleep(1000 + padding)

               Console.WriteLine("Task {0} releases the semaphore previous count: {1}.",
                                 Task.CurrentId, semaphore.Release())
            End Sub )
      Next

      ' Wait for half a second, to allow all the tasks to start and block.
      Thread.Sleep(500)

      ' Restore the semaphore count to its maximum value.
      Console.Write("Main thread calls Release(3) --> ")
      semaphore.Release(3)
      Console.WriteLine("{0} tasks can enter the semaphore.",
                        semaphore.CurrentCount)
      ' Main thread waits for the tasks to complete.
      Task.WaitAll(tasks)

      Console.WriteLine("Main thread exits.")
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System.Threading，代码行数:51，代码来源:SemaphoreSlim

输出：

0 tasks can enter the semaphore.
Task 1 begins and waits for the semaphore.
Task 5 begins and waits for the semaphore.
Task 2 begins and waits for the semaphore.
Task 4 begins and waits for the semaphore.
Task 3 begins and waits for the semaphore.
Main thread calls Release(3) --> 3 tasks can enter the semaphore.
Task 4 enters the semaphore.
Task 1 enters the semaphore.
Task 3 enters the semaphore.
Task 4 releases the semaphore; previous count: 0.
Task 2 enters the semaphore.
Task 1 releases the semaphore; previous count: 0.
Task 3 releases the semaphore; previous count: 0.
Task 5 enters the semaphore.
Task 2 releases the semaphore; previous count: 1.
Task 5 releases the semaphore; previous count: 2.
Main thread exits.

注：本文中的System.Threading.SemaphoreSlim类示例由纯净天空整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。