VB.NET IConvertible接口代码示例

OGeek|极客世界-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.IConvertible接口的典型用法代码示例。如果您正苦于以下问题：VB.NET IConvertible接口的具体用法？VB.NET IConvertible怎么用？VB.NET IConvertible使用的例子？那么恭喜您, 这里精选的接口代码示例或许可以为您提供帮助。

在下文中一共展示了IConvertible接口的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: New

Public Class Complex : Implements IConvertible
   Private x, y As Double

   Public Sub New(ByVal x As Double, ByVal y As Double)
      Me.x = x
      Me.y = y
   End Sub

   Function GetDoubleValue() As Double
      Return Math.Sqrt((x * x + y * y))
   End Function

   ' The remaining code provides IConvertible method implementations.
   Public Function GetTypeCode() As TypeCode Implements IConvertible.GetTypeCode
      Return TypeCode.Object
   End Function

   Function ToBoolean(ByVal provider As IFormatProvider) As Boolean _
            Implements IConvertible.ToBoolean
      Return x <> 0 OrElse y <> 0
   End Function

   Function ToByte(ByVal provider As IFormatProvider) As Byte Implements IConvertible.ToByte
       Return Convert.ToByte(GetDoubleValue())
   End Function

   Function ToChar(ByVal provider As IFormatProvider) As Char Implements IConvertible.ToChar
      Return Convert.ToChar(GetDoubleValue())
   End Function

   Function ToDateTime(ByVal provider As IFormatProvider) As DateTime Implements IConvertible.ToDateTime
      Return Convert.ToDateTime(GetDoubleValue())
   End Function

   Function ToDecimal(ByVal provider As IFormatProvider) As Decimal Implements IConvertible.ToDecimal
      Return Convert.ToDecimal(GetDoubleValue())
   End Function

   Function ToDouble(ByVal provider As IFormatProvider) As Double Implements IConvertible.ToDouble
      Return GetDoubleValue()
   End Function

   Function ToInt16(ByVal provider As IFormatProvider) As Short Implements IConvertible.ToInt16
      Return Convert.ToInt16(GetDoubleValue())
   End Function

   Function ToInt32(ByVal provider As IFormatProvider) As Integer Implements IConvertible.ToInt32
      Return Convert.ToInt32(GetDoubleValue())
   End Function

   Function ToInt64(ByVal provider As IFormatProvider) As Long Implements IConvertible.ToInt64
      Return Convert.ToInt64(GetDoubleValue())
   End Function

   Function ToSByte(ByVal provider As IFormatProvider) As SByte Implements IConvertible.ToSByte
      Return Convert.ToSByte(GetDoubleValue())
   End Function

   Function ToSingle(ByVal provider As IFormatProvider) As Single Implements IConvertible.ToSingle
      Return Convert.ToSingle(GetDoubleValue())
   End Function

   Overloads Function ToString(ByVal provider As IFormatProvider) As String Implements IConvertible.ToString
      Return String.Format("({0}, {1})", x, y)
   End Function

   Function ToType(ByVal conversionType As Type, ByVal provider As IFormatProvider) As Object Implements IConvertible.ToType
      Return Convert.ChangeType(GetDoubleValue(), conversionType)
   End Function

   Function ToUInt16(ByVal provider As IFormatProvider) As UInt16 Implements IConvertible.ToUInt16
      Return Convert.ToUInt16(GetDoubleValue())
   End Function

   Function ToUInt32(ByVal provider As IFormatProvider) As UInt32 Implements IConvertible.ToUInt32
      Return Convert.ToUInt32(GetDoubleValue())
   End Function

   Function ToUInt64(ByVal provider As IFormatProvider) As UInt64 Implements IConvertible.ToUInt64
      Return Convert.ToUInt64(GetDoubleValue())
   End Function
End Class

Public Module Example
   Sub Main()
      Dim testComplex As New Complex(4, 7)

      WriteObjectInfo(testComplex)
      WriteObjectInfo(Convert.ToBoolean(testComplex))
      WriteObjectInfo(Convert.ToDecimal(testComplex))
      WriteObjectInfo(Convert.ToString(testComplex))
   End Sub

   Sub WriteObjectInfo(ByVal testObject As Object)
      Dim typeCode As TypeCode = Type.GetTypeCode(testObject.GetType())

      Select Case typeCode
         Case typeCode.Boolean
            Console.WriteLine("Boolean: {0}", testObject)

         Case typeCode.Double
            Console.WriteLine("Double: {0}", testObject)

         Case Else
            Console.WriteLine("{0}: {1}", typeCode.ToString(), testObject)
      End Select
   End Sub
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:108，代码来源:IConvertible

注：本文中的System.IConvertible接口示例整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。